Section 3: Power Calculations for Correlations;

 I. Test rho=0 with t-distribution method
II. Test rho=c with Fisher's Z method


I. Compute the power of a test to detect one correlation = 0, t dist method

The program included here computes the power tables found in Jacob Cohen's
"Statistical Power Analysis for the Behavioral Sciences", Second Edition

Results from this PROC POWER procedure match Tables 3.3.1 - 3.3.6
found on pages 84-95.


OPTIONS NODATE;

%LET sides=2;   * ENTER: sides= 1 or 2;
%LET alpha=.01; * ENTER: desired p-value (alpha = .01 .05 .10);

ODS OUTPUT OUTPUT=t_pwr_cr(drop=analysis index);
ODS EXCLUDE output;

PROC POWER;
  ONECORR dist=t
  MODEL= random
  SIDES = &sides.
  ALPHA = &alpha.
  CORR = .1 .3 .5 .7 .9
  NTOTAL = 8 to 40 by 1 42 to 60 by 2
  POWER = .
;
RUN;

/*
Round the power calculations to match Cohen's results.
Note: These power calculations are close, though do not match exactly,
      especially as rho gets close to 1
*/

DATA t_pwr_cr;
SET t_pwr_cr;
n = ntotal;
pwr=100*ROUND(power,.01); * round power to the nearest two-digit integer;
IF power > .995 THEN pwr = .;
IF info eq ' ' THEN OUTPUT ;
RUN;

/*proc print DATA=t_pwr_cr NOobs; run;*/

PROC TABULATE DATA=t_pwr_cr NOseps;
CLASS Alpha corr n Sides ;* StdDev;
VAR pwr;
TABLE n, sides="Sides"*alpha="Alpha: Type I Error"*
     corr='Correlation'*pwr=' '*sum=' '*f=4.0
      / rts=12 Box='Power of T-test for HO: rho=0' misstext='*';
OPTIONS ps=99;
RUN;



II. Test rho=c with Fisher's Z method

< to follow >